AVR & ARDUINO

Каталог статей

Метод GSM_SMS remoteNumber()

Описание

Метод объекта GSM_SMS извлекает из входящего SMS-сообщения телефонный номер отправителя и сохраняет его в массив.

Синтаксис

SMS.remoteNumber(number, size);

Параметры

SMS - объект класса GSM_SMS.

number - массив символов (буфер) для хранения номера отправителя.

size - int, размер массива.

Возвращаемые значения

int - В асинхронном режиме remoteNumber() может возвращать следующие значения: 0 - если последняя вызванная команда еще выполняется, 1 - если последняя команда успешно выполнена и >1 - в случае ошибки. В синхронном режиме функция возвращает 1 при успешном выполнении, 0 - в случае ошибки.

Пример

// подключаем библиотеку
#include <GSM.h>

// PIN-код. Если на вашей SIM-карте установлен PIN-код - укажите его
#define PINNUMBER ""

// объявляем экземпляр класса
GSM gsmAccess; // для включения режима отладки добавьте параметр 'true'
GSM_SMS sms;
 
char remoteNumber[20]; // буфер для хранения входящего номера телефона
 
void setup()
{
 // инициализируем последовательный интерфейс передачи данных
 Serial.begin(9600);
 
 Serial.println("SMS Messages Receiver");
 
 // состояние соединения
 boolean notConnected = true;
 
 // запускаем GSM-плату расширения
 // если на вашей SIM-карте установлен PIN-код - укажите его в качестве параметра функции begin()
 while(notConnected)
 {
 if(gsmAccess.begin(PINNUMBER)==GSM_READY)
 notConnected = false;
 else
 {
 Serial.println("Not connected");
 delay(1000);
 }
 }
 
 Serial.println("GSM initialized");
 Serial.println("Waiting for messages");
}
 
void loop()
{
 char c;
 
 // если есть непрочитанные SMS 
 if (sms.available())
 {
 Serial.println("Message received from:");
 
 // получаем входящий номер телефона
 sms.remoteNumber(remoteNumber, 20);
 Serial.println(remoteNumber);
 
 // Ниже просто показан пример удаления сообщений:
 // Сообщения, начинающиеся с символа "#", необходимо игнорировать
 if(sms.peek()=='#')
 {
 Serial.println("Discarded SMS");
 sms.flush();
 }
 
 // побайтово считываем и выводим текст сообщения
 while(c=sms.read())
 Serial.print(c);
 
 Serial.println("\nEND OF MESSAGE");
 
 // удаляем сообщение из памяти модема
 sms.flush();
 Serial.println("MESSAGE DELETED");
 }
 
 delay(1000);
 
}